wglUseFontBitmaps

Aus DGL Wiki
Version vom 16. November 2010, 18:57 Uhr von Mikescher (Diskussion | Beiträge)

(Unterschied) ← Nächstältere Version | Aktuelle Version (Unterschied) | Nächstjüngere Version → (Unterschied)
Wechseln zu: Navigation, Suche

wglUseFontBitmaps

Name

wglUseFontBitmaps - Erzeugt aus der Schrifteinstellungen des Device Context eine Reihe von glBitmap Befehlen für die Buchstaben und speichert diese in Displaylisten.

Delphi-Spezifikation

function wglUseFontBitmaps (DC: HDC; first, count, listBase: DWORD): BOOL;



Parameter

DC Ein Display Context mit entsprechenden Font-Einstellungen.
first Mit welchen Zeichen soll begonnen werden
count Anzahl der zu erzeugenden Listen/Zeichen
listBase Der Name/Index der Liste für das erste Zeichen



Beschreibung

Die Schrifteinstellungen des Device Contextes werden genutzt, um mit glBitmap-Befehlen die angebenen Zeichen in Displaylisten zu speichern. Wenn ein Fehler auftritt, wird statt true, false zurückgegeben und der Fehler kann über GetLastError abgerufen werden.

Hinweise

Jede Display Liste erhält logischerweise nur einen glBitmap Aufruf.

Da der glBitmap Befehl genutzt wird ändert sich die Rasterposition nach aufruf einer Liste.

Falls für ein Zeichen in der gewählten Schrift keine Daten vorliegen wird für dieses Zeichen eine leere Displayliste zurückgegeben.

Die durch diese Funktion unter Windows zur Verfügung stehende Schrift hat eine festgelegte Größe und ist logischerweise nur 2D. Möchte man eine 3D-Schrift haben so kann man dafür den Befehl wglUseFontOutlines benutzen.

Beispiel

Zum Erstellen der Bitmapfonts gibt es wie üblich mehrere Wege. Einmal den Weg direkt über die Windowsapi oder den Weg über die Delphiklasse TFont. Das Zeichnen bleibt bei beiden gleich. Aus diesem Grund ist es auch vom Rest ein wenig getrennt.

Procedural

var
  FontLists: Cardinal;


procedure CreateLists; // Wird einmal am Anfang aufgerufen
var
  CustomFont: HFont;
begin
  FontLists := glGenLists(256);
  

  // CustomFont := GetStockObject (SYSTEM_FONT);
  // Eine Alternative mit der man die Systemschriftart zurück bekommt.
  

  CustomFont := CreateFont(
                           32,                  // Höhe
                           0,                   // Breite 0=Keine Vorgabe
                           0,
                           0,
                           0,                   // Fett?
                           0,                   // Kursiv?
                           0,                   // Unterstrichen?
                           0,                   // Durchgestrichen?
                           ANSI_CHARSET,
                           OUT_TT_PRECIS,
                           CLIP_DEFAULT_PRECIS,
                           NONANTIALIASED_QUALITY,
                           FF_DONTCARE or DEFAULT_PITCH,
                           'Times New Roman');  // Name der Schrift
  

  SelectObject(DC, CustomFont);               // Font auf einen Device Context benutzen
  wglUseFontBitmaps (DC, 0, 255, FontLists);  // Mit selektiertem Font Zeichen erstellen
end;

Objekt orientiert

var
  Font: TFont;


procedure CreateLists; // Wird einmal am Anfang aufgerufen
begin
  FontLists := glGenLists(256);
  

  Font := TFont.Create;  // Instanz einer Fontklasse erstellen
  try
    Font.Name := 'Times New Roman'; // Name
    Font.Size := 32;                // Schriftgröße
    Font.Style := [fsBold];         // Styles (fsBold, fsItalic, ...)
    

    SelectObject(DC, Font.Handle);              // Font auf einen Device Context benutzen
    wglUseFontBitmaps (DC, 0, 255, FontLists);  // Mit selektiertem Font Zeichen erstellen
  finally
    FreeAndNil(Font);  // erstellte Instanz wieder frei geben
  end;
end;

Bitmapfonts benutzen

procedure ShowText(pText: AnsiString);
begin
   glListBase(FontLists);  // Liste auswählen
   glCallLists(Length(pText), GL_UNSIGNED_BYTE, Pointer(pText));  // Entsprechende Listen aufrufen
end;


procedure Draw;  // Zeichen Routine
begin
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
  glColor3f(1,0.5,0);        // Aktuelle Farbe für glRasterPos festlegen
  glRasterPos3f(-0.1,0,-1);  // (sichtbare) Rasterposition eintellen
  ShowText('OpenGL ');
  ShowText('Wiki');          // Steht nach "OpenGL" da glBitmap die Rasterposition verschiebt.
end;

Siehe auch

glBitmap, glListBase, glCallLists, wglUseFontOutlines